[MathJax on]

2 The Small Class Number Library

2.1 Functions

2.1-1 SmallClassNrGroup

Returns the i-th finite group of class number k in the library. Alternatively, the pair [ k, i] can be given as a single argument id. If the group is solvable, it is given as a PcGroup whose Pcgs is a SpecialPcgs. If the group is not solvable, it will be given as a permutation group of minimal permutation degree and with a minimal generating set.

gap> G := SmallClassNrGroup( 6, 4 );
<pc group of size 18 with 3 generators>
gap> NrConjugacyClasses( G );
6
gap> IsDihedralGroup( G );
true

2.1-2 SmallClassNrGroupsAvailable

Returns true if the finite groups of class number k are available in the library, and false otherwise.

gap> SmallClassNrGroupsAvailable( 14 );
true
gap> SmallClassNrGroupsAvailable( 15 );
false

2.1-3 AllSmallClassNrGroups

Returns all finite groups with certain properties as specified by arg. The arguments must come in pairs consisting of a function and a value (or list of possible values). At least one of the functions must be NrConjugacyClasses. Missing functions will be interpreted as NrConjugacyClasses, missing values as true.

gap> L1 := AllSmallClassNrGroups( [3..5], IsNilpotent );
[ <pc group of size 3 with 1 generator>,
  <pc group of size 4 with 2 generators>,
  <pc group of size 4 with 2 generators>,
  <pc group of size 5 with 1 generator>,
  <pc group of size 8 with 3 generators>,
  <pc group of size 8 with 3 generators> ]
gap> List( L1, NrConjugacyClasses );
[ 3, 4, 4, 5, 5, 5 ]
gap> L2 := AllSmallClassNrGroups( IsSolvable, true, NrConjugacyClasses, 6 );
[ <pc group of size 6 with 2 generators>,
  <pc group of size 12 with 3 generators>,
  <pc group of size 12 with 3 generators>,
  <pc group of size 18 with 3 generators>,
  <pc group of size 18 with 3 generators>,
  <pc group of size 36 with 4 generators>,
  <pc group of size 72 with 5 generators> ]
gap> ForAll( L2, G -> IsSolvable( G ) and NrConjugacyClasses( G ) = 6 );
true

2.1-4 OneSmallClassNrGroup

Returns one finite group with certain properties as specified by arg. The arguments must come in pairs consisting of a function and a value (or list of possible values). At least one of the functions must be NrConjugacyClasses. Missing functions will be interpreted as NrConjugacyClasses, missing values as true.

gap> H := OneSmallClassNrGroup( 6, IsAbelian );
<pc group of size 6 with 2 generators>
gap> IsCyclic( H );
true
gap> K := OneSmallClassNrGroup( 10, IsSolvable, true, IsNilpotent, false );
<pc group of size 28 with 3 generators>
gap> NrConjugacyClasses( K ) = 10 and IsSolvable( K ) and not IsNilpotent( K );
true

2.1-5 NrSmallClassNrGroups

Returns the number of finite groups with certain properties as specified by arg. The arguments must come in pairs consisting of a function and a value (or list of possible values). At least one of the functions must be NrConjugacyClasses. Missing functions will be interpreted as NrConjugacyClasses, missing values as true.

gap> NrSmallClassNrGroups( 14 );
93
gap> NrSmallClassNrGroups( [3..5], IsNilpotentGroup );
6
gap> NrSmallClassNrGroups( IsSolvable, true, NrConjugacyClasses, 6 );
7

2.1-6 IteratorSmallClassNrGroups

Returns an iterator that iterates over the finite groups with properties as specified by arg. The arguments must come in pairs consisting of a function and a value (or list of possible values). At least one of the functions must be NrConjugacyClasses. Missing functions will be interpreted as NrConjugacyClasses, missing values as true.

gap> iter := IteratorSmallClassNrGroups( IsSolvable, false, 11 );
<iterator>
gap> for G in iter do Print( Size( G ), "\n" ); od;
336
720
720
1344
1344
1512
2448
29120

2.1-7 IdClassNr

Returns the SmallClassNr ID of G, i.e. a pair [k, i] such that G is isomorphic to SmallClassNrGroup( k, i ).

gap> IdClassNr( AlternatingGroup( 5 ) );
[ 5, 8 ]
gap> A := SmallClassNrGroup( 5, 8 );
Group([ (1,2,3), (1,4,5) ])
gap> IsAlternatingGroup( A );
true

generated by GAPDoc2HTML